Cos'è ElectroYou | Login Iscriviti

ElectroYou - la comunità dei professionisti del mondo elettrico

2
voti

Thevenin e l'asincrono

Articolo n° 2 su 3 del corso "Thevenin forever". Vai all'indice del corso.

Paragrafi dell'articolo:

  1. Caratteristica meccanica del motore asincrono
  2. Il flusso della potenza attiva
  3. Il circuito equivalente
  4. Calcolo della corrente di rotore con Thevenin
  5. Tracciamento dei grafici con Scilab
  6. Bibliografia

Caratteristica meccanica del motore asincrono

Come illustrato in altre parti del sito è il grafico che mostra l'andamento della coppia all'albero della machina in funzione della velocità di rotazione. Si può ricavare determinando la potenza che arriva all'albero, rappresentandola come "dissipazione" su una particolare resistenza fittizia che è funzione della velocità. Qui utilizzeremo per i calcoli circuitali il teorema di Thevenin. L'idea è nata leggendo il libro citato nella bibliografia che proponeva anche un programma in Matlab, qui rielaborato e  leggermente ampliato per Scilab.

Il flusso della potenza attiva

Il flusso di potenza in un motore asincrono è rappresentato nella figura

che corrisponde all'equazione

Il circuito equivalente

Il circuito èquivalente del motore asincrono, trascurando le perdite nel ferro è. I parametri si ricavano dai dati della prova a vuoto ed a rotore bloccato, come qui illustrato.

La coppia elettromagnetica generata in un motore asincrono  è data da

Calcolo della corrente di rotore con Thevenin

Per calcolare la corrente di rotore ricaviamo il generatore equivalente visto da AB, immaginando aperto il ramo con X2.

Si otterrà il circuito

Tracciamento dei grafici con Scilab

Le formule in blu, più precise,  sono usate nel seguente programma Scilab che traccia il grafico della caratteristica meccanica. Sono tracciate cinque caratteristiche che si differenziano per il valore della resistenza di rotore:

  • R2->nero;
  • 2R2->blu;
  • 3R2->verde;
  • 4R2->cyan;
  • 5R2->rosso.

Nel grafico sono anche tracciate con gli stessi colori, ma tratteggiate, le curve che si ricaverebbero approssimando ulteriormente il generatore di Thevenin (formule in rosso).

Il programma basta copiarlo ed incollarlo nella finestra di Scilab. Ovviamente si presuppone un minimo di conoscenza che, se non si possiede, può essere iniziata leggendo questo articolo.

Dati del motore di esempio (modificabili da programma, che, è bene avvertire, non ha controlli di coerenza dei dati)

  • U=460
  • f=60 Hz
  • p=2
  • Pu=18 kW
  • R1=0,641 ohm
  • X1=1,106 ohm
  • R2=0,332 ohm
  • X2=0,464 ohm
  • Xm=26,3 ohm

Il programma

//Parametri dell'asincrono
txt=['resistenza di statore: R1=';'reattanza di statore X1=';'resistenza di rotore: R2=';
'reattanza di rotore: X2=';'reattanza di magnetizzazione: Xm=';
'Tensione di alimentazione U=';'frequenza f:=';'n. poli:2p=';'potenza:Pn='];
As=evstr(x_mdialog('Dati del motore',txt,['0.641';'1.106';'0.332';'0.464';'26.3';
'460';'60';'4';'18']));
//terna a PIGRECO
r1=As(1);
x1=As(2);
r2=As(3);
x2=As(4);
xm=As(5);
v_phase=As(6)/sqrt(3);
f=As(7);
np=As(8);
Pn=As(9);
n_sync=120*f/np;
w_sync=2*%pi*n_sync/60;
j=%i*1;
//Circuito equivalente di Thevenin equazione 7-41a e 7-43
v_th=v_phase*(xm/sqrt(r1^2+(x1+xm)^2));
z_th=((j*xm)*(r1+j*x1))/(r1+j*(x1+xm));
r_th=real(z_th);
x_th=imag(z_th);
s=linspace(0,1,51);
//Caratteristica meccanica con Thevenin  più preciso
s(1)=0.001; // per evitare Division by zero;
nm=(1-s)*n_sync; // velocità meccanica
for k=1:5,
for ii=1:51,
   t_ind1(ii)=(3*v_th^2*(k*r2)/s(ii))/(w_sync*((r_th+(k*r2)/s(ii))^2+(x_th+x2)^2));
end
//Plotta
plot2d(nm,t_ind1,style=k);
end;
//Caratteristica meccanica con Thevenin  approssimato
v_th=v_phase;
r_th=r1;
x_th=x1;
for k=1:5,
for ii=1:51,
   t_ind1(ii)=(3*v_th^2*(k*r2)/s(ii))/(w_sync*((r_th+(k*r2)/s(ii))^2+(x_th+x2)^2));
end
//Plotta
plot2d(nm,t_ind1,style=k);
e=gce();
e.children.line_style=3;
end;
a=gca();
a.title.text="Caratteristiche meccaniche di un asincrono";
a.x_label.text="rpm";
a.y_label.text="Coppia (N m)";

Bibliografia

Electric machinery and Power System Fundamentals – Stephen J. Chapman-Mc Graw Hill 

0

Commenti e note

Inserisci un commento

Inserisci un commento

Per inserire commenti è necessario iscriversi ad ElectroYou. Se sei già iscritto, effettua il login.