esercizio trifase

[RenzoDF]

... alla fine mi sono solo impantanato

Sui calcoli? ... cerco di indovinare ... sulla rappresentazione fasoriale dei generatori?

------------------------------------------------------------------------
Edit 18:00

... io farei in questo modo; userei solo due generatori per imporre la terna dissimmetrica,

Sorgente FidoCadJ | Ingrandisci | Cos'è Fidocad

scegliendo U12 a fase zero, calcolando l'argomento alfa di U32 con Carnot ed usando Millman per la Up2; non mi va di perdere tempo con Latex (e quindi mi merito dei sacrosanti punti negativi) ma mi faccio aiutare dall'inseparabile SpeQ ; ecco i veloci calcoli, tutti da ricontrollare

2013-02-23_180356.gif (32.03 KiB) Osservato 1942 volte

--------------------------------------------------------------------------------------
Edit 18:30


... ... e visto che tu sei un utilizzatore di Scilab, ho appena controllato i calcoli con il mio vecchio script
http://www.electroyou.it/renzodf/wiki/articolo3

inserendo i dati della rete, dopo aver numerato i nodi come segue

Sorgente FidoCadJ | Ingrandisci | Cos'è Fidocad

Codice: Seleziona tutto

 
  //-----------------------------------------------------------
//     Copyright   RenzoDF 2008
//-------------------------------------------------------------
   format('v',6); j=%i; k0=%pi/180;
//-------- cartesiana --> polare ----------
function[mf]=cp(c)
   mf=[abs(c),phasemag(c)]; 
endfunction
//------ polare --> cartesiana ------------
function [c] = PC(m,f)
  if argn(2) == 1 then
    c = m(:,1:2:$).*cos(m(:,2:2:$)*k0) + j*m(:,1:2:$).*sin(m(:,2:2:$)*k0);
  elseif argn(2) == 2 then  c = m.*cos(f*k0) + j*m.*sin(f*k0);
  end
endfunction
     //--------------------------------------------------------
    //     INSERIRE gli elementi dei rami della rete 
   //    secondo l'ordine indicato nel commento
m=[... 
   //-----nodo-------generatore-------impedenza----generatore---
  // inizio| fine |   tensione     (o resistenza)   corrente
//   q    |   w  |      E        |      Z       |     J       |
//-------------------------------------------------------------
      1        2    PC(465,0)             0          0       ;   
      1        3    PC(445,62.147)        0          0       ;
      2        4        0              0.15+j*0.11   0       ;
      1        5        0              0.15+j*0.2    0       ;
      3        6        0              0.15+j*0.15   0       ;     
      4        7        0                 5+j*7      0       ;
      5        7        0                 5+j*7      0       ;
      6        7        0                 5+j*7      0       ;
      4        9        0             1.429+j*2.474  0       ;
      5        9        0             1.429+j*2.474  0       ;
      6        9        0             1.429+j*2.474  0       ;
      4        8        0                6+j*5.5     0       ;
      5        8        0                6+j*5.5     0       ;
      6        8        0                6+j*5.5     0           
     
];
  //-----------------------------------------------------------
// estraggo sottomatrice (1^ e 2^ colonna di m)
  y= real(m(:,1:2));
// determino "numero di nodi"
  nn=max(y);
// determino "numero di rami" (righe matrice m) 
  nr=size(m,1);
//-----------------------------------------------   
s=0;
for i=1 : nr
// se J==0 e Z==0 incremento n.rami anomali
     if   m(i,5) == 0 then s=  s + 1 ;
       end
end; neq=nn+s ;  // faccio spazio in A() e b() 
//-----------------------------------------------
// azzero coefficienti,termini noti,correnti di ramo
    A=zeros(neq,neq); b=zeros(neq,1); I=zeros(nr,1);
//
// costruisco matrice A() e vettore b()
r = 1;
for k=1 : nr
q=y(k,1); w=y(k,2); E=m(k,3); Z=m(k,4); J=m(k,5);
   if J<>0 then 
        b(q)=b(q)+J;
        b(w)=b(w)-J;
   
  elseif Z<>0 then // se J==0 e Z<>0
        A(q,q)=A(q,q)-1/Z;
        A(w,w)=A(w,w)-1/Z;
        A(q,w)=A(q,w)+1/Z;
        A(w,q)=A(w,q)+1/Z;
        b(q)=b(q)+ E/Z;
        b(w)=b(w)- E/Z;
         
      else // se J==0 e Z==0
           A(nn+r,q)=-1;      //-Vi
           A(nn+r,w)=+1;     //+Vf
           b(nn+r)  = E;    // = E
           A(q,nn+r)=-1;   //  -Ik
           A(w,nn+r)=+1;  //   +Ik
         r=r+1;
      end
  end
  // per comodita' pongo V(1) = 0
// nodo n°1=nodo di riferimento
// ed elimino 1^riga e 1^colonna
   A2=A([2:$],[2:$]); b2=b([2:$],1);
   V2 = A2\b2; // calcolo V(2)...V(nn)
   V   =[0;V2] // aggiungo V(1)=0       
  //--------------------------------------> out V()
// Calcolo le correnti nei rami con verso
// da "nodo inizio" a -> "nodo fine"
r=1; 
for k=1:nr
q=y(k,1); w=y(k,2); E=m(k,3); Z=m(k,4); J=m(k,5);
if J<>0 then I(k)= J; 
elseif Z<>0 then I(k)=((V(q)-V(w))+ E)/Z;
    // se Z<>0 uso legge Ohm generalizzata
     else I(k)=V(nn+r);//se Z=0 pesco I dal fondo di V()
     r=r+1;
  end
end
//-------OUT correnti di ramo--------------
                Ic = I 
//-------------------------------------------- eof


una volta mandato in run, per avere la corrente basta un I + Enter e un V + Enter per ottenere correnti
e tensioni di ramo

2013-02-23_184509.gif (21.7 KiB) Osservato 1928 volte

ed infine un

Codice: Seleziona tutto

Sg=V(2)*conj(I(1))+V(3)*conj(I(2))

e un

Codice: Seleziona tutto

Su=(V(4)-V(9))*conj(I(9))+(V(5)-V(9))*conj(I(10))+(V(6)-V(9))*conj(I(11))

per ottenere potenza complessa erogata dai generatori e assorbita dal carico B

2013-02-23_185117.gif (3.89 KiB) Osservato 1928 volte

[tipu91]

Invece io voto positivamente perché come al solito sei stato gentilissimo.. Inoltre il nome del file SpeQ (roccotrif) è stupendo

Sui calcoli? ... cerco di indovinare ... sulla rappresentazione fasoriale dei generatori?

no no, non ho avuto tempo di fare i calcoli, perché da ieri pomeriggio mi sto preparando per l'ipotetico (tocco qualsiasi oggetto metallico nei paraggi) ORALE!!! ma non penso di trovare problemi con i calcoli, alla fine, tolta la "trappola", il problema è un esercizio standard... intendevo che ho mi sono impantanato in una dimostrazione facile, avventurandomi in una più difficile

BTW ti consiglio di vedere il trifase del compito di ieri quando lo pubblica.. ha mandato in tilt tanta gente con un'altra "trappola"

BTW2 questa è la dimostrazione che ti dicevo:

DIMOSTRAZIONE

electroy 1.JPG (48.95 KiB) Osservato 1937 volte

FIGURA DI RIFERIMENTO

electroy 2.JPG (37.88 KiB) Osservato 1937 volte

http://www.dsea.unipi.it/Members/rizzow/Members/rizzow/trifase_file_x_stampa_unico.pdf
altrimenti a questo link (SLIDE 34)

[RenzoDF]

... e la dimostrazione, con il procedimento suggerito in precedenza dovrebbe essere la seguente:

Sorgente FidoCadJ | Ingrandisci | Cos'è Fidocad

percorso VERDE+BLU (linea 1):



percorso ROSSO+BLU (linea 2):



infine uguagliando le due equazioni si ha:



dalla quale possiamo eliminare i termini

Con questa "dimostrazione" hai solo dimostrato che la differenza di potenziale fra due punti (i due centri stella O e O') risulta uguale se calcolata lungo due diversi percorsi (rosso e verde) dimostrazione che direi non aveva bisogno di dimostrazione ...

... ma non che la differenza di potenziale fra i suddetti punti sia nulla ... .


E ripeto che la "dimostrazione" della slide di Rizzo

rr.gif (19.19 KiB) Osservato 1917 volte

la trovo completamente assurda, in quanto se si studiano le reti trifasi non si può non conoscere il teorema di Millman, dal quale discende (banalmente) che in presenza di tre punti a potenziale V1, V2 e V3 (rispetto ad un generico punto 0),

Sorgente FidoCadJ | Ingrandisci | Cos'è Fidocad

i potenziali dei centri stella H e K di due stelle equilibrate saranno per forza uguali in quanto, banalmente



NB e sempre con Millman si può dimostrare che questa uguaglianza esiste anche in presenza
di stelle squilibrate con pari rapporto R fra impedenze corrispondenti, ovvero se



in quanto

[aglieglie007]

"se abbiamo due stelle equilibrate, alimentate dalla stessa terna, i loro centri stella vanno ad assumere lo stesso potenziale",
... penso non ci sia nulla.

con la linea dissimmetrica non credevo si potesse fare!!Che ignorant!!
Moolto gentile RenzoDF....addirittura i conti!
GRAZIE