E' possibile integrare nel portale uno schematic editor?

[phylum]

mah è veramente strano - ho semplicemente compilato questo script:
http://sourceforge.net/p/fidocadj/discu ... /cb12d947/
che è quello della .23.7, con l'ultima versione di NSIS e cambiato il jar all'interno. Il risultato deve essere NECESSARIAMENTE lo stesso - comunque cerco di capire con quale versione di NSIS è stato compilato il vecchio - magari il bug è li

[DarwinNE]

Ragazzi, io sentitamente ringrazio entrambi, state facendo un lavoro meraviglioso!

[phylum]

np

@elettrodomus prova a installarlo SENZA selezionare guida utente, in pratica non usare le checkbox vai solo avanti e dimmi cosa succede

[elettrodomus]

E' andato al primo colpo.

[phylum]

Ok ;) in pratica quando scegli la guida ti toglie fidocad dall'installazione !
sto correggendo lo script, non avendolo sviluppato io - non potevo saperlo ;)

[phylum]

intanto prova(te) questo http://phylum2.altervista.org/_FidoCadJ_v.0.24.1.exe

una domanda: mi pare di ricordare che si era parlato di manuale in cinese e altro ? o le sinapsi mi giocano brutti scherzi

per i posteri:

Codice: Seleziona tutto

; Best Compression
SetCompress Auto
SetCompressor /SOLID lzma
SetCompressorDictSize 32
SetDatablockOptimize On
!include "MUI.nsh"
!include "Sections.nsh"

Name "FidoCadJ"
Caption "FidoCadJ 0.24.1"
OutFile "FidoCadJ_v.0.24.1.exe"
RequestExecutionLevel admin
InstallDir "$PROGRAMFILES\FidoCadJ"

#-------------------------------- Interface Configuration --------------------------------#
  AutoCloseWindow false
  ShowInstDetails show
  XPStyle on
  CheckBitmap ".\colorful.bmp"

  !define MULTIUSER_INSTALLMODE_DEFAULT_CURRENTUSER
  !define MUI_COMPONENTSPAGE_SMALLDESC
  !define MUI_HEADERIMAGE ".\icona_fidocadj_128x128.bmp"
  !define MUI_HEADERIMAGE_BITMAP ".\install.bmp"
  !define MUI_WELCOMEFINISHPAGE_BITMAP ".\fidocadj.bmp"
  !define MUI_ABORTWARNING
  !define MUI_ICON ".\orange-install.ico"
  !define MUI_UNICON ".\orange-uninstall.ico"

#------------------------------- Installer pages --------------------------------#

  !insertmacro MUI_PAGE_WELCOME
  !insertmacro MUI_PAGE_LICENSE ".\License.txt"
  !insertmacro MUI_PAGE_COMPONENTS
  !insertmacro MUI_PAGE_DIRECTORY
  !insertmacro MUI_PAGE_INSTFILES

  !define MUI_FINISHPAGE_RUN
  !define MUI_FINISHPAGE_RUN_FUNCTION "RunLink"
  !insertmacro MUI_PAGE_FINISH

#------------------------------- Uninstaller pages --------------------------------#
  !insertmacro MUI_UNPAGE_CONFIRM
  !insertmacro MUI_UNPAGE_INSTFILES
;  !insertmacro MUI_UNPAGE_FINISH

#------------------------------- choice of languages for installation --------------------------------#

  !insertmacro MUI_LANGUAGE "Italian"
  !insertmacro MUI_LANGUAGE "English"
  !insertmacro MUI_LANGUAGE "French"
  !insertmacro MUI_LANGUAGE "Spanish"

#------------------------------- Version Information Installer --------------------------------#

  VIProductVersion "0.24.1.0"
  VIAddVersionKey /LANG=${LANG_ITALIAN} "ProductName" "FidoCadJ"
  VIAddVersionKey /LANG=${LANG_ITALIAN} "Comments" "http://sourceforge.net/projects/fidocadj/"
  VIAddVersionKey /LANG=${LANG_ITALIAN} "LegalCopyright" "Copyright © 2007-2012 Davide Bucci"
  VIAddVersionKey /LANG=${LANG_ITALIAN} "FileDescription" "Setup FidoCadJ"
  VIAddVersionKey /LANG=${LANG_ITALIAN} "FileVersion" "0.24.1"
;VIAddVersionKey /LANG=${LANG_ITALIAN} "CompanyName" "Davide Bucci"
;VIAddVersionKey /LANG=${LANG_ITALIAN} "LegalTrademarks" "Davide Bucci"

;Definitions

!define SHCNE_ASSOCCHANGED 0x8000000
!define SHCNF_IDLIST 0

#------------------------------- The stuff to install --------------------------------#

  Section "!FidoCadJ" Required
   SectionIn RO
    SetOutPath $INSTDIR 

     ;--- Put file there ---;
      File "fidocadj.jar"
      File "FidoCadJ.ico"
      File "web.ico"

     ;--- Write the installation path into the registry ---;
      WriteRegStr HKLM "SOFTWARE\FidoCadJ" "Install_Dir" "$INSTDIR"

     ;--- Write the uninstall keys for Windows ---;
      WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\FidoCadJ" "DisplayName" "FidoCadJ"
      WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\FidoCadJ" "UninstallString" '"$INSTDIR\uninstall.exe"'
      WriteRegDWORD HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\FidoCadJ" "NoModify" 1
      WriteRegDWORD HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\FidoCadJ" "NoRepair" 1
      WriteUninstaller "uninstall.exe"

     ${If} $R0 == "javaw.exe"
       StrCpy $R0 "$PROGRAMFILES\\Java\jre6\bin\javaw.exe"
        ${EndIf}

     ;--- creating shortcut on desktop ---;       
       CreateShortCut "$DESKTOP\FidoCadJ.lnk" "$R0" `-jar "$INSTDIR\fidocadj.jar" ` "$INSTDIR\FidoCadJ.ico" 0

     ;--- creating directory on star menu ---;
      CreateDirectory "$SMPROGRAMS\FidoCadJ"

     ;--- creating shortcut on star menu ---;
      CreateShortCut "$SMPROGRAMS\FidoCadJ\FidoCadJ.lnk" "$R0" `-jar "$INSTDIR\fidocadj.jar" ` "$INSTDIR\FidoCadJ.ico" 0
      CreateShortCut "$SMPROGRAMS\FidoCadJ\$(Site)" "http://davbucci.chez-alice.fr/index.php?argument=elettronica/fidocadj/fidocadj.inc&language=$(webLanguage)" "" "$INSTDIR\web.ico" 0
      CreateShortCut "$SMPROGRAMS\FidoCadJ\$(Uninstall)" "$INSTDIR\uninstall.exe" "" "$INSTDIR\uninstall.exe" 0
    SectionEnd
   #--- end common files here ---#

    Section "$(AssociateFiles) FidoCadJ" FCD_FILES
   #--- association FCD files ---#
      File "fidocad_files.ico"
      WriteRegStr HKCR ".fcd" "" "FidoCadJ.Document"
      WriteRegStr HKCR "FidoCadJ.Document" "" "FidoCadJ File"
      WriteRegStr HKCR "FidoCadJ.Document\DefaultIcon" "" "$INSTDIR\fidocad_files.ico"
      WriteRegStr HKCR "FidoCadJ.Document\shell" "" "open"
      WriteRegStr HKCR "FidoCadJ.Document\shell\open\command" "" '"$R0" -jar "$INSTDIR\fidocadj.jar" "%1"'
      System::Call 'Shell32::SHChangeNotify(i ${SHCNE_ASSOCCHANGED}, i ${SHCNF_IDLIST}, i 0, i 0)'
    SectionEnd
   #--- association FCD files here ---#

   #--- init manual files here ---#
    Section /o "Guida utente" SEC_ITA
      ;--- ITA files here ---;
      CreateShortCut "$SMPROGRAMS\FidoCadJ\$(Manual)" "$INSTDIR\$(FileManual)" "" "$INSTDIR\$(FileManual)" 0
      File "fidocadj_manual_it.pdf"
    SectionEnd

    Section /o "User guide" SEC_ENG
      ;--- ENG files here ---;
      CreateShortCut "$SMPROGRAMS\FidoCadJ\$(Manual)" "$INSTDIR\$(FileManual)" "" "$INSTDIR\$(FileManual)" 0
      File "fidocadj_manual_en.pdf"
    SectionEnd

    Section /o "Guide de l'utilisateur" SEC_FRA
      ;--- FRA files here ---;
      CreateShortCut "$SMPROGRAMS\FidoCadJ\$(Manual)" "$INSTDIR\$(FileManual)" "" "$INSTDIR\$(FileManual)" 0
      File "fidocadj_manual_fr.pdf"
    SectionEnd

    Section /o "Guía del usuario (en Inglés)" SEC_ESP
      ;--- ESP files here ---;
      CreateShortCut "$SMPROGRAMS\FidoCadJ\$(Manual)" "$INSTDIR\$(FileManual)" "" "$INSTDIR\$(FileManual)" 0
      File "fidocadj_manual_en.pdf"
    SectionEnd
   #--- end manual files here ---#

#------------------------------- Descriptions optional components -------------------------------#

  !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
    !insertmacro MUI_DESCRIPTION_TEXT ${SEC_ITA} "Installa il manuale italiano di FidoCadJ."
    !insertmacro MUI_DESCRIPTION_TEXT ${SEC_ENG} "Install the manual english FidoCadJ."
    !insertmacro MUI_DESCRIPTION_TEXT ${SEC_FRA} "Installez manuel en français FidoCadJ."
    !insertmacro MUI_DESCRIPTION_TEXT ${SEC_ESP} "Instale el inglés FidoCadJ manual."
  !insertmacro MUI_FUNCTION_DESCRIPTION_END


#------------------------------- run at startup Installer -------------------------------#

  Function .onInit   
    !insertmacro MUI_LANGDLL_DISPLAY
    StrCpy $1 ${Required}

    Call GetJRE
    Pop $R0

    ${If} $R0 == "javaw.exe"
      ${If} $LANGUAGE == ${LANG_ITALIAN}
        Messagebox MB_OK "In questo sistema non è installato un JRE Java.$\nVisita http://www.java.com/it per installare l'ultima versione di Java."
      ${EndIf}
      ${If} $LANGUAGE == ${LANG_ENGLISH}
        Messagebox MB_OK "In this system does not have a Java JRE.$\nVisit http://www.java.com/it to install the latest version of Java."
      ${EndIf}
      ${If} $LANGUAGE == ${LANG_FRENCH}
        Messagebox MB_OK "Dans ce système ne dispose pas d'un Java JRE.$\nVisitez http://www.java.com/it pour installer la dernière version de Java."
      ${EndIf}
      ${If} $LANGUAGE ==  ${LANG_SPANISH} 
        Messagebox MB_OK "En este sistema no tiene un JRE de Java.$\nVisite http://www.java.com/it para instalar la última versión de Java."
      ${EndIf}
      ExecShell "" "http://www.java.com"
      Quit
    ${EndIf}

  FunctionEnd

#------------------------------- Language Strings -------------------------------#

  LangString FileRequired ${LANG_ITALIAN} "necessari"
  LangString FileRequired ${LANG_ENGLISH} "required"
  LangString FileRequired ${LANG_FRENCH} "nécessaires"
  LangString FileRequired ${LANG_SPANISH} "necesario"

  LangString Uninstall ${LANG_ITALIAN} "Disinstalla FidoCadJ.lnk"
  LangString Uninstall ${LANG_ENGLISH} "Uninstall FidoCadJ.lnk"
  LangString Uninstall ${LANG_FRENCH} "Désinstaller FidoCadJ.lnk"
  LangString Uninstall ${LANG_SPANISH} "Desinstalar FidoCadJ.lnk"

  LangString Manual ${LANG_ITALIAN} "Guida utente di FidoCadJ.lnk"
  LangString Manual ${LANG_ENGLISH} "FidocadJ User Guide.lnk"
  LangString Manual ${LANG_FRENCH} "Guide de l'utilisateur FidoCadJ.lnk"
  LangString Manual ${LANG_SPANISH} "Guía del usuario FidoCadJ.lnk"

  LangString AssociateFiles ${LANG_ITALIAN} "Associa i files fcd a"
  LangString AssociateFiles ${LANG_ENGLISH} "Associate files fcd to"
  LangString AssociateFiles ${LANG_FRENCH} "Associés files fcd à"
  LangString AssociateFiles ${LANG_SPANISH} "Asociados files fcd a"

  LangString Site ${LANG_ITALIAN} "Il sito di FidoCadJ.lnk"
  LangString Site ${LANG_ENGLISH} "The site FidoCadJ.lnk"
  LangString Site ${LANG_FRENCH} "Le site de FidoCadJ.lnk"
  LangString Site ${LANG_SPANISH} "El sitio FidoCadJ.lnk"

  LangString webLanguage ${LANG_ITALIAN} "Italiano"
  LangString webLanguage ${LANG_ENGLISH} "English"
  LangString webLanguage ${LANG_FRENCH} "Francais"
  LangString webLanguage ${LANG_SPANISH} "English"

  LangString ShortCutDesk ${LANG_ITALIAN} "Collegamento su Desktop"
  LangString ShortCutDesk ${LANG_ENGLISH} "Desktop shortcut"
  LangString ShortCutDesk ${LANG_FRENCH} "Raccourci Desktop"
  LangString ShortCutDesk ${LANG_SPANISH} "Acceso directo del escritorio"

  LangString ShortCutStart ${LANG_ITALIAN} "Collegamento su Start Menu"
  LangString ShortCutStart ${LANG_ENGLISH} "Shortcut to Start Menu"
  LangString ShortCutStart ${LANG_FRENCH} "Raccourci pour Start Menu"
  LangString ShortCutStart ${LANG_SPANISH} "Acceso directo al Start Menu"

  LangString FileManual ${LANG_ITALIAN} "fidocadj_manual_it.pdf"
  LangString FileManual ${LANG_ENGLISH} "fidocadj_manual_en.pdf"
  LangString FileManual ${LANG_FRENCH} "fidocadj_manual_fr.pdf"
  LangString FileManual ${LANG_SPANISH} "fidocadj_manual_en.pdf"

#------------------------------- Section Uninstaller -------------------------------#

  Section "Uninstall"
   #--- Remove registry keys ---#
    DeleteRegValue HKCU "Software\Microsoft\Windows\CurrentVersion\Run" "FidoCadJ"
    DeleteRegKey HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\FidoCadJ"
    DeleteRegKey HKLM "Software\FidoCadJ"
    DeleteRegKey HKCU "Software\FidoCadJ"

    ReadRegStr $R0 HKCR ".fcd" ""
    StrCmp $R0 "FidoCadJ.Document" 0 +2
    DeleteRegKey HKCR ".fcd" 

    DeleteRegKey HKCR "FidoCadJ.Document"
    System::Call 'Shell32::SHChangeNotify(i ${SHCNE_ASSOCCHANGED}, i ${SHCNF_IDLIST}, i 0, i 0)'

   #--- Remove files and uninstaller ---#
    Delete $INSTDIR\fidocadj.jar
    Delete $INSTDIR\fidocadj_manual_it.pdf
    Delete $INSTDIR\fidocadj_manual_en.pdf
    Delete $INSTDIR\fidocadj_manual_fr.pdf
    Delete $INSTDIR\fidocadj.ico
    Delete $INSTDIR\fidocad_files.ico
    Delete $INSTDIR\web.ico
    Delete $INSTDIR\Uninstall.exe

   #--- Remove shortcuts ---#
    Delete "$DESKTOP\FidoCadJ.lnk"
    Delete "$SMPROGRAMS\FidoCadJ\*.*"

   #--- Remove directories used ---#
    RMDir "$SMPROGRAMS\FidoCadJ"
    RMDir "$INSTDIR"
  SectionEnd

#------------------------------- run at startup Uninstaller -------------------------------#

  Function un.onInit
    !insertmacro MUI_UNGETLANGUAGE
  FunctionEnd

#------------------------------- RunLink Functions -------------------------------#

  Function RunLink
    ExecShell "" "$SMPROGRAMS\FidoCadJ\FidoCadJ.lnk"
  FunctionEnd

#------------------------------- Function GetJRE -------------------------------#
;
;         Find JRE (javaw.exe)
;         1 - in .\jre directory (JRE Installed with application)
;         2 - in JAVA_HOME environment variable
;         3 - in the registry
;         4 - assume javaw.exe in current dir or PATH

  Function GetJRE
    Push $R0
    Push $R1

    ClearErrors
    StrCpy $R0 "$EXEDIR\jre\bin\javaw.exe"
    IfFileExists $R0 JreFound
    StrCpy $R0 ""

    ClearErrors
    ReadEnvStr $R0 "JAVA_HOME"
    StrCpy $R0 "$R0\bin\javaw.exe"
    IfErrors 0 JreFound

    ClearErrors
    ReadRegStr $R1 HKLM "SOFTWARE\JavaSoft\Java Runtime Environment" "CurrentVersion"
    ReadRegStr $R0 HKLM "SOFTWARE\JavaSoft\Java Runtime Environment\$R1" "JavaHome"
    StrCpy $R0 "$R0\bin\javaw.exe"

    IfErrors 0 JreFound
    StrCpy $R0 "javaw.exe"     

    JreFound:
      Pop $R1
      Exch $R0
  FunctionEnd

# End script


[DarwinNE]

Certo! I manuali disponibili sono qui:

https://sourceforge.net/projects/fidoca ... s/manuals/

Quello in francese purtroppo è obsoleto... mi occupo già di quello in italiano e di quello in inglese, non riesco più ad aggiornare anche lui

[elettrodomus]

Ok. Funziona al primo colpo, anche spuntando il manuale.
In effetti avevo badato anch'io all'assenza del manuale in cinese..

[PietroBaima]

Dunque... è il primo messaggio-richiesta su fidocad...
Mi chiedevo se si potesse aggiungere nel form che si apre quando seleziono il pulsante "Testo" una piccola tabella con i caratteri più amati dagli elettronici, per esempio .

Purtroppo non mi ricordo mai il loro codice e quindi devo aprire tutte le volte "Mappa caratteri" di windows per cercarmi il carattere voluto

Sarebbe molto comodo e, penso, di difficoltà realizzativa modesta.

Anyway, se ho detto una stupidaggine bastonate pure

Ciao da Pietro

[IsidoroKZ]

Aggiungo anch'io una richiesta. Quando si esporta un disegno (lo faccio sempre a risoluzione massima e in png) il file ha una cornice ragionevole su tre lati, mentre la cornice in basso e` un po' piu` larga e talvolta devo croppare il disegno.

Il bordo in basso piu` largo e` voluto?