Numero abcde

[RenzoDF]

Ancora un problema numerico

Determinare un numero di cinque cifre tale che, aggiungendo una cifra pari ad "1" a destra dello stesso, si ottiene un nuovo numero (di 6 cifre) che risulta il triplo del numero che invece si otterrebbe aggiungendo la stessa cifra "1" alla sua sinistra.

[Galaxi93]

42857

[RenzoDF]

... bravissimo , ma spiega anche il metodo che hai seguito per risolverlo

[Galaxi93]

una semplice equazione di primo grado:

(x+100000)*3=10x+1

alla fine viene: 7x=299999 --> x=42857

[Cox]

a = (x*10)+1
b = (x+100.000)
a = 3b
a = 3 (x+100.000)
(x*10)+1= 3(x+100.000)
1 = 3x + 300.000 - 10x
1 = -7x + 300.000
7x = 299.000
x = 42857

mmmmmmmm.....??

[RenzoDF]

Visto che siete dei ragazzi in gamba ve ne faccio uno piu' simpatico

Ci sono 5 case in fila, di 5 diversi colori. In ogni casa vive 1 persona diversa
e ciascuno dei padroni di casa beve una bavanda diversa, fuma sigarette diverse, ha un animale diverso.

* Marco abita in una casa rossa
* Carlo ha un cane
* Dino beve thè
* La casa verde è a sinistra della casa bianca
* Il padrone della casa verde beve caffè
* La persona che fuma Alfa ha degli uccellini
* Il padrone della casa gialla fuma MS
* L'uomo che vive nella casa centrale beve latte
* Nino vive nella prima casa
* L'uomo che fuma le CAMEL vive vicino a quello che ha i gatti
* L'uomo che ha i cavalli vive vicino a quello che fuma MS
* L'uomo che fuma le DIANA beve birra
* Aldo fuma le Prins
* Nino vive vicino alla casa blù
* L'uomo che fuma le CAMEL ha un vicino che beve acqua

Di chi è il dromedario ?

[xyz]

Ci sono 5 case in fila, di 5 diversi colori. In ogni casa vive 1 persona diversa
e ciascuno dei padroni di casa beve una bavanda diversa, fuma sigarette diverse, ha un animale diverso.

Il quesito di Albert Einstein con piccoli cambiamenti

[angus]

Aldo

indovinello.jpg (14.38 KiB) Osservato 6781 volte

pare però non lo tenga in casa, ma in apposito recinto di colore viola.

[IsidoroKZ]

Il quesito di Albert Einstein con piccoli cambiamenti

Ma sara` proprio stato proposto da lui o e` una delle tante attribuzioni fasulle che fanno solo uso del suo nome?

[xyz]

Ma sara` proprio stato proposto da lui o e` una delle tante attribuzioni fasulle che fanno solo uso del suo nome?

Credo anch'io che sia uno delle tante attribuzioni fasulle come la frase: “Se un giorno le api dovessero scomparire, all'uomo resterebbero soltanto quattro anni di vita”. Comunque se uno cerca trova col suo nome il quesito con alcune sostituzioni di marche di sigarette e animali.

Io ho una soluzione fatta in Prolog alcuni anni fa', questo è l'adattamento fatto dal con un cerca e sostituisci:

Codice: Seleziona tutto

% #@ -*- Mode: Prolog -*-   vim:ts=8:syntax=prolog:

quesito(L) :-

   % 5 case
   % ordine: [posizione, nome, colore, bevanda, sigaretta, animale]

   L = [

      [1, _, _, _, _, _],
      [2, _, _, _, _, _],
      [3, _, _, _, _, _],
      [4, _, _, _, _, _],
      [5, _, _, _, _, _]
   ],

   % 1. Marco vive in una casa rossa

   member([_,marco, rossa, _, _,_], L),

   % 2. Carlo ha un cane

   member([_, carlo, _, _, _, cane], L),

   % 3. Dino beve thè

   member([_, dino, _, the, _, _], L),

   % 4. La casa verde è a sinistra della casa bianca

   member([P11, _, verde,  _, _, _], L),
   member([P21, _, bianca, _, _, _], L),
   P21 =:= P11 + 1,

   % 5. Il padrone della casa verde beve caffè

   member([_, _, verde, caffe, _, _], L),

   % 6. La persona che fuma Alfa ha degli uccellini

   member([_, _, _, _, alfa, uccellini], L),

   % 7. Il padrone della casa gialla fuma MS

   member([_, _, gialla, _, ms, _], L),

   % 8. L’uomo che vive nella casa centrale beve latte

   member([3, _, _, latte, _, _], L),

   % 9. Nino vive nella prima casa

   member([1, nino, _, _, _, _], L),

   % 10. L'uomo che fuma le Camel vive vicino a quello che ha i gatti

   member([P12, _, _, _, camel, _    ], L),
   member([P22, _, _, _, _    , gatti], L),
   abs(P12 - P22) =:= 1,

   % 11. L'uomo che ha i cavalli vive vicino a quello che fuma MS

   member([P13, _, _, _, _ , cavalli], L),
   member([P23, _, _, _, ms, _      ], L),
   abs(P13 - P23) =:= 1,

   % 12. L'uomo che fuma le Diana beve birra

   member([_, _, _, birra, diana, _], L),

   % 13. Aldo fuma le Prins

   member([_, aldo, _, _, prins, _], L),

   % 14. Nino vive vicino alla casa blù

   member([P14, nino, _  , _, _, _], L),
   member([P24, _,    blu, _, _, _], L),
   abs(P14 - P24) =:= 1,

   % 15. L'uomo che fuma le Camel ha un vicino che beve acqua

   member([P15, _, _, _    , camel, _], L),
   member([P25, _, _, acqua, _,      _], L),
   abs(P15 - P25) =:= 1,

   % il dromedario

   member([_, _, _, _, _, dromedario], L).

print_element([]).
print_element([[P, N, C, B, S, A]|L]) :-
   writef('Pos=%w Nome=%6lCol=%7lBev=%6lSig=%6lAnim=%w\n', [P, N, C, B, S, A]),
   print_element(L).

print_list([]).
print_list([X|L]) :-
   print_element(X),
   print_list(L).

go :-
   findall(X, quesito(X), L),
   print_list(L).

Per lanciarlo con SWI-Prolog se il file del programma si chiama "quesito.pl":

Codice: Seleziona tutto

$> swipl -s quesito.pl -g go -t halt

Risultato:

Codice: Seleziona tutto

Pos=1 Nome=nino  Col=gialla Bev=acqua Sig=ms    Anim=gatti
Pos=2 Nome=dino  Col=blu    Bev=the   Sig=camel Anim=cavalli
Pos=3 Nome=marco Col=rossa  Bev=latte Sig=alfa  Anim=uccellini
Pos=4 Nome=aldo  Col=verde  Bev=caffe Sig=prins Anim=dromedario
Pos=5 Nome=carlo Col=bianca Bev=birra Sig=diana Anim=cane

Questa è la stessa unica soluzione trovata anche da angus