Lettore tag rfid rc522

[ThEnGi]

Puoi indicarmi come fare per far andare il pin a livello "low" anzichè "High" per 1 secondo circa (non è poi così importante il tempo di low)

Codice: Seleziona tutto

//Nella zona di setup
pinMode(PIN, OUTPUT);
digitalWrite(PIN, HIGH); // Porto il pin a 1 (stato normale)
....
....
....
....
//Nel loop o nella tua funzione
digitalWrite(PIN, LOW); //Pin a 0
dealy(1000); // Aspetta 1 Sec, Bloccante !
digitalWrite(PIN, HIGH); //Pin a 1


Da implementare nel tuo codice, se non devi fare altro puoi usare delay !
Non sono un fan di delay, ma per una cosa così può anche andare bene, sappi che se uno passa un'altra carta mentre il programma è all'interno della funzione delay non recepisci l'input

[GioArca67]

Tutti i led? Anche quello rosso?

Se sì :
Nel setup subito dopo

Codice: Seleziona tutto

   pinMode(greenLedPins[i], OUTPUT);


e prima della graffa chiusa
aggiungi

Codice: Seleziona tutto

   digitalWrite(greenLedPins[i], HIGH);


Idem subito dopo quella del led rosso

Codice: Seleziona tutto

   digitalWrite(RED_LED_PIN, HIGH);


così imposti le uscite alte.

Poi nella blinkLed scambi HIGH e LOW

[GioArca67]

ThEnGi forse al posto di [code] hai usato [quote]

[ThEnGi]

EDIT: Mancava anche un ";"

[GioArca67]

... e come ha giustamente fatto ThEnGi puoi togliere il secondo delay

Fai attenzione che la blinkLed viene chiamata con un parametro (duration) che non usi.
Potrebbe essere utile sostituire il 1000/2 nel delay con duration, e quando chiami la funzione metti nel secondo parametro il tempo in cui ti serve il pin basso.
Inoltre ormai cambierei il nome alla funzione blinkLed ed ai pin LED...

[teletommy]

Grazie amici, ci provo in giornata e faccio sapere. Spero di aver capito tutto. Grazie ancora a voi

[djnz]

...poi bisognerebbe sostituire le stringhe dinamiche C++ (oggetti String) con "normali" stringhe C (array di char null terminated), per evitare la frammentazione della (poca) memoria e il conseguente blocco imprevedibile di Arduino sul medio/lungo periodo

Se non ho sbagliato qualcosa questo potrebbe essere un modo:

Codice: Seleziona tutto

#include <MFRC522.h>
const uint8_t RED_LED_PIN = 1;
const uint8_t GREENLEDS[] = { 2, 3, 4, 5, 6, 7, 8 };
const uint8_t MAXBUF = 15;     // lunghezza chiavi + 1
const uint8_t USERSNUM = 7;    // quantita`chiavi conosciute
char readUid[MAXBUF] = { 0 };  // uid ricevuto
MFRC522 rfid(10, 9);

// array chiavi conosciute
const char users[USERSNUM][MAXBUF] = { "0475d5b8700000",
                                       "049abab6700000",
                                       "04b9bab6700000",
                                       "04d9bab6700000",
                                       "04f7bab6700000",
                                       "04c3c0b6700000",
                                       "04e2c0b6700000" };

//--------------------------------------------------------------

void setup()
{
  uint8_t i;

  SPI.begin();
  rfid.PCD_Init();
  pinMode(RED_LED_PIN, OUTPUT);
  for (i = 0; i < USERSNUM; i++)
    pinMode(GREENLEDS[i], OUTPUT);
}

//--------------------------------------------------------------

void loop()
{
  int8_t n;

  if (rfid.PICC_IsNewCardPresent() &&
      rfid.PICC_ReadCardSerial())
  {
    getUID(readUid);
    rfid.PICC_HaltA();
    n = checkUID(readUid);
    if (-1 == n)
      blinkLed(RED_LED_PIN, 250, 8);
    else
      blinkLed(GREENLEDS[n], 1000, 1);
  }
  delay(50);
}

//--------------------------------------------------------------

void getUID(char u[])
{
  uint8_t j = 0;
  uint8_t i;
  uint8_t n;

  for (i = 0; i < rfid.uid.size; i++)
  {
    n = rfid.uid.uidByte[i];
    u[j] = toHex(n >> 4);
    j += j < (MAXBUF - 1);
    u[j] = toHex(n & 15);
    j += j < (MAXBUF - 1);
  }
  u[j] = 0;
}

//--------------------------------------------------------------

char toHex(uint8_t n)
{
  return (n < 10)  ?  n + '0'  :  n - 10 + 'a';
}

//--------------------------------------------------------------

int8_t checkUID(char u[])
{
  uint8_t i;

  for (i = 0; i < USERSNUM; i++)
    if (0 == strcmp(users[i], u))
      return i;
  return -1;
}

//--------------------------------------------------------------

void blinkLed(uint8_t led, uint16_t duration, uint8_t repeat)
{
  uint8_t n;

  for (n = 0; n < repeat; n++)
  {
    digitalWrite(led, HIGH);
    delay(duration);
    digitalWrite(led, LOW);
    if (n < repeat-1)
      delay(duration);
  }
}

//--------------------------------------------------------------

[ridiculouslab]

Buongiorno a tutti.
Se può essere di spunto ho usato lo stesso rc522 con un microcontrollore PIC.
Sul mio sito a questo link puoi scaricare il codice in c..
https://www.ridiculouslab.com/arguments/iot/rfid/rfid.php

Il codice non sarà molto bello ma funge..