Abstract

Lo script si riferisce alla risoluzione della rete, comunque asimmetrica e squilibrata, attraverso il calcolo della V_o'o usando Millman e ricavando successivamente le correnti di linea .
Il diagramma vettoriale e' ridotto all'essenziale per non appesantire lo script.

Fig.1 rete trifase

Successivamente si calcolano le indicazioni di tre wattmetri in inserzione Righi e si calcola Ptot e Qtot.

Lo script Scilab

clear
 clc
 clf
 format('v',6)

// Definisco j per evitare %i .... molto scomodo  ! ecc.

 j=%i;  pi=%pi;  r3=sqrt(3);   // definisco j pi r3
 k=10;          // Fattore di amplificazione x grafico correnti
 O=0+j*0;    // origine assi

// Dati iniziali

 V=400; z1=10+j*8; z2=-j*16; z3=18-j*8;

// Trasformaz. da cartesiana a polare

 function[mf]=r2p(c)
 mf=[abs(c),atan(imag(c),real(c))*180/pi]
 endfunction

// Calcolo stellate (per questo esempio suppongo alimentazione simmetrica)

 E=V/r3;  e1=E*exp(j*pi/2);  e2=E*exp(-j*pi/6);  e3=E*exp(-j*pi*5/6);

// Applico Millman per Vo'o

 vo=(e1/z1+e2/z2+e3/z3)/(1/z1+1/z2+1/z3),  vop=r2p(vo);

// Ricavo le correnti in forma cartesiana e polare

 i1=(e1-vo)/z1;   i2=(e2-vo)/z2;   i3=(e3-vo)/z3;
 i=[i1;i2;i3] ,   ip=r2p(i)      

// Traccio box scale e griglia

 plot2d(0,0,rect=[-300,-300,300,300])
 xgrid

// Traccio stellate

 xstring(-15,-30,'O')
 xstring(10,230,'1'), xstring(210,-125,'2'), xstring(-220,-125,'3')
 oi=O;                                // collegando O con 1 2 3 O'
 e=[oi,e1,oi,e2,oi,e3,oi,vo]; 
 xarrows(real(e),imag(e),200,4)

// Traccio le tensioni di fase

 oi=vo;                               // tracciando da O' a 1 2 3 
 ef=[oi,e1,oi,e2,oi,e3];
 xarrows(real(ef),imag(ef),200,3)

// Traccio concatenate

 v=[e2,e1,e1,e3,e3,e2];             // tracciando da 2 a 1 ecc.
 xarrows(real(v),imag(v),200,1)

// Traccio correnti

 oi=vo/k  ;                         //con origine O' ... translandole
 i=[oi,oi+i1,oi,oi+i2,oi,oi+i3]*k; 
 xarrows(real(i),imag(i),200,[5 6 7])
 legends(['I1';'I2';'I3'],[5,6 7],opt="ul")

// Wattmetri in Righi usando la potenza apparente complessa S=V*conj(I)

 w13=real((e1-e3)*conj(i1))
 w23=real((e2-e3)*conj(i2))
 w3_12=real((e1-e2)*conj(i3))

// Potenza attiva e reattiva totale

 Ptot=w13+w23,      Qtot=(w13-w23+2*w3_12)/r3

// e le Si assorbite (nella forma Pi + j Qi) relative a ogni Zi

 s1=(e1-vo)*conj(i1),   s2=(e2-vo)*conj(i2),   s3=(e3-vo)*conj(i3)

// le Si si possono sommare perche' in forma complessa !!! ;)

 st=s1+s2+s3

// il risultato è pari a Ptot + j Qtot ?

 st==Ptot+j*Qtot

Risultato

Non riporto l'output completo di Scilab ma solo il diagramma vettoriale finale.

Fig.2 Diagramma vettoriale