elettrodo di riferimentooo

[belva87]

Yes, alimentato...
Lo so che il condensatore è facilmente reperibile in SMD, per il valore standard non saprei non ho controllato...
Ho provato inserendo 10p e 68p e l'influenza è minima sulla banda bassante, non ho però inserito la vk200, per la perlina... è una prova da fare, ma mi sento di dire che preferirei (anche per esperienza) un vk200 a fare da filtro per l'RF...
Aspetto allora che riesci a far girare Win, e che giulia ci faccia sapere qualcosa...

[giulia87]

vedo che continuate a scrivervi (notifiche by mail), ho lanciato un topico proprio interessante allora

adesso sto studiando per un esame, e quindi riprendo in mano il tutto tra 10 giorni, quando definirò in modo definitivo la catena di filtraggio e amplificazione...
devo imparare a usare LT, è molto difficile?
un'altra cosa...posso simulare usando componenti non della LT (tipo i miei operazionali sono della burr brown) ?

[DarwinNE]

Lo so che il condensatore è facilmente reperibile in SMD, per il valore standard non saprei non ho controllato...

http://fr.farnell.com/avx/04025u0r5bat2 ... dp/7567995
C'è da dire che potrebbero bastare le capacità parassite dello stampato a superare il picofarad, in effetti il condensatore è troppo piccolino.

Ho provato inserendo 10p e 68p e l'influenza è minima sulla banda bassante, non ho però inserito la vk200,

E' normale che tu non veda l'influenza sulla banda passante se utilizzi per simulare un elettrodo un generatore di tensione ideale. E' probabile che tu inizi a vedere un effetto se ci metti una resistenza in serie ed inizi ad aumentarla. Per esempio, con , dovresti vedere che il polo introdotto dal condensatore C1 si sposta verso il basso, e così fa lo zero introdotto da C2 che si abbassa pure. Magari in un'applicazione realistica si può alzare un po' C2, ma non troppo.

Aspetto allora che riesci a far girare Win, e che giulia ci faccia sapere qualcosa...

Ok, adesso sono ancora al lavoro, ma nel fine settimana se ho tempo vedo di fare qualcosa (ma tu allega il file )

adesso sto studiando per un esame, e quindi riprendo in mano il tutto tra 10 giorni, quando definirò in modo definitivo la catena di filtraggio e amplificazione...

In bocca al lupo allora

devo imparare a usare LT, è molto difficile?

Imparare su quale bottone bisogna cliccare per lanciare una simulazione è facilissimo.
Però per utilizzare un simulatore circuitale bisogna conoscere l'elettronica meglio di lui, ma quello non è un problema del programma. Per riuscire a non farsi fregare da un grafico colorato... ci vuole un sacco di esperienza, io ancora imparo un sacco di cose ogni volta che lancio Spice

un'altra cosa...posso simulare usando componenti non della LT (tipo i miei operazionali sono della burr brown)?

Certo che puoi, ammesso di utilizzare il modello corretto.
Però ci sarebbe da discutere su cosa vuol dire "modello corretto"... Se mi è concesso riprendere una citazione di un grande, confondere il modello con la realtà è come entrare in un ristorante e mangiarsi il menu!

[DarwinNE]

Dunque, faccio un piccolo aggiornamento alla questione.
Non sono riuscito a far ripartire la mia macchina virtuale contenente Windows. Si lamenta che c'è un file hal.dll che manca e non parte del tutto. Non dovrebbe essere un problema rinfrescare il sistema, se non ché non so dove più ho messo la mia copia di Win XP... Quando salterà fuori, vedrò di ripristinare il sistema.

Ricordiamo prima di tutto il problema iniziale, che è quello di amplificare di 30dB un segnale proveniente da una matrice di elettrodi disposti su dei neuroni. E' presente un elettrodo di riferimento ed il circuito va fabbricato in una sessantina di esemplari, il che richiede di mantenerne bassa la complessità. La banda richiesta è quella telefonica, da 300Hz a 3kHz e sarebbe preferibile cercare di ridurre il più possibile il disturbo a 50Hz proveniente dalla rete elettrica. Non è dato sapere l'impedenza di un neurone, ma penso che sia utile fare in modo che il circuito abbia un ingresso che carichi il meno possibile l'elettrodo.

Non volevo però rimanere del tutto a bocca asciutta dopo aver proposto una possibile soluzione, e quindi ho rispolverato una versione di Spice 3f5 che avevo installato sul MacOSX. Si tratta della versione distribuita da Berkeley, che ha dato origine alle varie personalizzazioni che si trovano nei vari software (LTspice, Altium designer, ...). Non la uso proprio tutti i giorni, ma l'impressione generale che ne ho ricavato in questi ultimi anni è che si possono fare tante cose, ma rispetto alle versioni commerciali ogni tanto c'è qualche problema di convergenza, perlomeno nella simulazione transitorio.
Mentre programmi come LTspice permettono di introdurre un circuito in forma grafica, Spice richiede una descrizione in formato testo, che in gergo si chiama una netlist. Anche utilizzando i programmi con editor grafici, conviene sempre avere un'idea di come funzioni il formato delle netlist, perché la maggior parte di essi se ne serve per comunicare con la propria versione adattata di Spice.
Si tratta di un formato molto semplice, in pratica si danno dei nomi ai vari nodi del circuito e poi si provvede a disporre i vari compontenti dicendo fra quali nodi vanno posti. Iniziamo quindi a fornire il circuito, con evidenziati i nodi, è lo stesso che avevo fornito qualche tempo fa, ma ho ritoccato il valore di qualche componente. I nomi dei nodi sono i numeretti disegnati in rosso nello schema.

Sorgente FidoCadJ | Ingrandisci | Cos'è Fidocad

Per simulare gli operazionali, si può procedere a cercare un modello nella biblioteca di qualche fabbricante, oppure si può cercare di costruirselo da sé, andando a leggersi la sterminata letteratura che esiste in merito.
Io ho spesso utilizzato i modelli presi da questa pagina:

http://www.ecircuitcenter.com/opmodels/OpampModels.htm

Una lettura molto interessante è anche questa application note:

http://www.analog.com/static/imported-f ... 6AN138.pdf

Possiamo partire da un operazionale di tipo TL082. E' abbastanza veloce, non è troppo critico, è facilissimo da reperire ed è economico. Non cerchiamo operazionali di precisione per applicazioni in cui la precisione non serve, non cerchiamo bande passanti fantasmagoriche per poi ritrovarci amplificatori che autooscillano mettendo all'uscita un cavo coassiale (cosa che peraltro può benissimo succedere anche al TL082).
Leggendo un po' di datasheet e modificando il modello di livello 3 della pagina web che ho citato, sono arrivato a questo:

Codice: Seleziona tutto

* OPAMP MACRO MODEL (INTERMEDIATE LEVEL)
* WITH OUTPUT VOLTAGE LIMITING
*                IN+ IN- OUT  VCC  VEE
.SUBCKT OPAMP3   1   2   81   101   102 
Q1 5 1 7 NPN
Q2 6 2 8 NPN
RC1 101 5 5.17e2
RC2 101 6 5.17e2
RE1 7 4 4.66e2
RE2 8 4 4.66e2
I1 4 102 0.001
*
* OPEN-LOOP GAIN, FIRST POLE AND SLEW RATE
G1 100 10 6 5 0.0104719
RP1 10 100 1.03e8
CP1 10 100 7.76e-5uF
*
* CURRENT LIMIT
D1 10 82 DILIM
VL1 82 81 DC 0.186V
D2 83 10 DILIM
VL2 81 83 DC 0.186V
.model DILIM D(IS=1E-15)
*
*OUTPUT STAGE
EOUT 80 100 10 100 1
RO 80 81 100
*
* INTERNAL REFERENCE
RREF1 101 103 100K
RREF2 103 102 100K
EREF 100 0 103 0 1
R100 100 0 1MEG
*
.model NPN  NPN(BF=50000)
*
.ENDS


Non che non sia criticabile, il TL082 utilizza un ingresso a JFET mentre nel modello si continua ad utilizzare dei bipolari per rappresentare lo stadio di ingresso. In particolare, ho cercato di rappresentare la limitazione in corrente dello stadio di uscita.
Un'altra possibilità la troviamo sul sito di Texas Instruments, dove è scaricabile gratuitamente un modello che loro forniscono per il TL082, però utilizza alcune estensioni che non sono compatibili con la mia versione di Spice.
Si può certamente fare di meglio, ma io non passerei troppo tempo a simulare un circuito del genere: si accende il saldatore e lo si monta!

Ecco quindi la netlist completa. Ci sono due modelli di operazionale, uno è quello di cui ho parlato sopra, l'altro invece è una rappresentazione piuttosto semplicistica, tant'è che neppure richiede alimentazione!

Codice: Seleziona tutto

* Circuito acquisizione segnali biologici banda 300Hz-3kHz con filtro notch 50Hz

Vin 3 0 DC 0V AC 1mV
Vcc 1 0 DC 15V
Vee 2 0 DC -15V

C1 3 4 68pF
L1 4 5 3nH
C2 5 0 0.5pF
R1 5 0 10Megohm
* X1 5 6 7 OPAMP1
X1 5 6 7 1 2 OPAMP3

R2 6 0 4.7kohm
R3 6 7 150kohm
C3 6 7 180pF
R4 7 8 96.46kohm
C7 8 0 66nF
R5 8 10 96.46kohm
C5 7 9 33nF
C6 9 10 33nF
R6 9 0 48.22k
* X2 10 11 12 OPAMP1
X2 10 11 12 1 2 OPAMP3
R8 11 0 4.7kohm
R7 11 12 150kohm
C8 11 12 470pF

.TRAN
.AC DEC 100 1 1MEG
.PRINT AC V(3)
.PRINT AC V(5)
.PRINT AC V(7)
.PRINT AC V(10)
.PRINT AC V(12)

* SINGLE-POLE OPERATIONAL AMPLIFIER MACRO-MODEL
* connections:      non-inverting input
*                   |   inverting input
*                   |   |   output
*                   |   |   |
.SUBCKT OPAMP1      1   2   6
* INPUT IMPEDANCE
RIN     1          2          10MEG
* DC GAIN (100K) AND POLE 1 (100HZ)
EP1 3 0 1 2 100K
RP1 3 4 1K
CP1 4 0 1.5915uF
* OUTPUT BUFFER AND RESISTANCE
EOUT 5 0 4 0 1
ROUT 5 6 10
.ENDS



* OPAMP MACRO MODEL (INTERMEDIATE LEVEL)
* WITH OUTPUT VOLTAGE LIMITING
*                IN+ IN- OUT  VCC  VEE
.SUBCKT OPAMP3   1   2   81   101   102 
Q1 5 1 7 NPN
Q2 6 2 8 NPN
RC1 101 5 5.17e2
RC2 101 6 5.17e2
RE1 7 4 4.66e2
RE2 8 4 4.66e2
I1 4 102 0.001
*
* OPEN-LOOP GAIN, FIRST POLE AND SLEW RATE
G1 100 10 6 5 0.0104719
RP1 10 100 1.03e8
CP1 10 100 7.76e-5uF
*
* CURRENT LIMIT
D1 10 82 DILIM
VL1 82 81 DC 0.186V
D2 83 10 DILIM
VL2 81 83 DC 0.186V
.model DILIM D(IS=1E-15)
*
*OUTPUT STAGE
EOUT 80 100 10 100 1
RO 80 81 100
*
* INTERNAL REFERENCE
RREF1 101 103 100K
RREF2 103 102 100K
EREF 100 0 103 0 1
R100 100 0 1MEG
*
.model NPN  NPN(BF=50000)
*
.ENDS


Facciamo una prima analisi del circuito. Mi sono interessato in particolare all'analisi AC, che viene fatta calcolando il punto di lavoro del circuito, linearizzando i componenti attorno al punto di lavoro e poi risolvendo il circuito linearizzato nel dominio della frequenza. Si tratta quindi di una simulazione che non può dare conto di effetti di saturazione o non lineari e che quindi non è adatta a studiare cose tipo la distorsione armonica, mentre è perfetta per determinare la banda passante di un circuito quando tutto funziona bene.
Ho introdotto dapprima i valori mostrati nel circuito sopra per vedere se avevo fatto i calcoli corretti, in particolare per essere sicuro che il filtro notch filtrasse effettivamente a 50 Hz.
Ho in un secondo tempo rifatto i conti utilizzando valori di resistenze standard all'1%, per essere sicuro che questa soluzione fosse effettivamente praticabile. Per i condensatori, quello da 66nF si potrà realizzare con un parallelo tra due condensatori di 33nF:

Sorgente FidoCadJ | Ingrandisci | Cos'è Fidocad

La figura qui di seguito mostra, in rosso, la simulazione effettuata con il filtro notch originale ed in verde, con il filtro realizzato con valori standard:

Risultati analisi AC

analysis.png (6.95 KiB) Osservato 3491 volte

Si vede come il fatto di aver rotto leggermente la simmetria del circuito faccia sì che il filtro notch intervenga su una frequenza leggermente diversa ed abbia un pozzo meno "profondo" di quello con i componenti più ideali. Non credo che la cosa sia un problema nell'utilizzazione pratica, perché l'attenuazione resta più che buona a 50 Hz:

Risultati analisi AC, zoom attorno a 50 Hz

analysis_prec.png (5.22 KiB) Osservato 3491 volte

Tra l'altro, la profondità del filtro con i valori "teorici" non è infinita, perché ho riportato i valori con quattro cifre significative.
Ma non è il caso di spaccare il capello in quattro.

Naturalmente, il discorso non è finito qui, si potrebbero far variare le caratteristiche degli operazionali, si potrebbe fare uno studio Monte Carlo sui componenti per vedere che tolleranza è necessaria, si potrebbe vedere cosa succede con un'analisi di tipo transitorio e apprezzare la distorsione armonica... Ma io a questo punto lo monterei, il circuitino

Volendo utilizzare due operazionali in più, potrei studiare un filtro anti aliasing più efficiente di quel poco che ho messo qui (due poli e due zeri messi a naso).

[DarwinNE]

Dato che avete proposto circuiti con quattro operazionali, non voglio essere da meno

Supponiamo che la nostra amica voglia campionare ad 8 bit intorno ai 20 kHz come frequenza di campionamento. Se tolleriamo un errore di un bit meno significativo per l'aliasing, vuole dire che il nostro filtro passa basso non basta e che bisogna fare qualcosa di più selettivo.

Questo è quanto ho messo a punto, aggiungendo un filtro ellittico CC 04 08 31 all'uscita del circuito precedente. Alcuni valori sono stati ritoccati (ed ho spostato di posto il condensatore C8).

Sorgente FidoCadJ | Ingrandisci | Cos'è Fidocad

Il codice per lanciare una simulazione AC con Spice3f5 è il seguente:

Codice: Seleziona tutto

* Circuito acquisizione segnali biologici banda 300Hz-3kHz con filtro notch 50Hz

Vin 3 0 DC 0V AC 1mV
Vcc 1 0 DC 15V
Vee 2 0 DC -15V

C1 3 4 68pF
L1 4 5 3nH
C2 5 0 0.5pF
R1 5 0 10Megohm
* X1 5 6 7 OPAMP1
X1 5 6 7 1 2 OPAMP3

R2 6 0 4.7kohm
R3 6 7 180kohm
C3 6 7 20pF
R4 7 8 95.3kohm
C7 8 0 66nF
R5 8 10 95.3kohm
C5 7 9 33nF
C6 9 10 33nF
R6 9 0 47.5k

* X2 10 11 12 OPAMP1
X2 10 11 12 1 2 OPAMP3

R8 11 0 4.7kohm
R7 11 12 180kohm

R9 15 16 10.43k
R10 12 13 7.093k
R11 12 14 25.14k
R12 14 0 3.977k
R13 15 0 2.859k
C8 13 16 5.884nF
C9 13 15 5.884nF
X3 14 15 16 1 2 OPAMP3

R14 16 17 10k
R15 17 18 10k
C10 17 19 18.95nF
C11 18 0 0.9396nF
X4 18 19 19 1 2 OPAMP3

.AC    DEC    100 1 1MEG

.PRINT AC V(3)
.PRINT AC V(5)
.PRINT AC V(7)
.PRINT AC V(10)
.PRINT AC V(12)
.PRINT AC V(16)
.PRINT AC V(19)

* SINGLE-POLE OPERATIONAL AMPLIFIER MACRO-MODEL
* connections:      non-inverting input
*                   |   inverting input
*                   |   |   output
*                   |   |   |
.SUBCKT OPAMP1      1   2   6
* INPUT IMPEDANCE
RIN     1          2          10MEG
* DC GAIN (100K) AND POLE 1 (100HZ)
EP1   3 0   1 2   100K
RP1   3   4   1K
CP1   4   0   1.5915uF
* OUTPUT BUFFER AND RESISTANCE
EOUT   5 0   4 0   1
ROUT   5   6   10
.ENDS



* OPAMP MACRO MODEL (INTERMEDIATE LEVEL)
* WITH OUTPUT VOLTAGE LIMITING
*                IN+ IN- OUT  VCC  VEE
.SUBCKT OPAMP3   1   2   81   101   102 
Q1   5 1   7   NPN
Q2   6 2   8   NPN
RC1   101   5   95.49
RC2   101   6   95.49
RE1   7   4   43.79
RE2   8   4   43.79
I1   4   102   0.001
*
* OPEN-LOOP GAIN, FIRST POLE AND SLEW RATE
G1   100 10   6 5 0.0104719
RP1   10   100   9.549MEG
CP1   10   100   0.0016667UF
*
* CURRENT LIMIT
D1   10   82   DILIM
VL1   82   81   DC   0.186V
D2   83   10   DILIM
VL2   81   83   DC   0.186V
.model   DILIM   D(IS=1E-15)
*
*OUTPUT STAGE
EOUT   80 100   10 100   1
RO   80   81   100
*
* INTERNAL REFERENCE
RREF1   101   103   100K
RREF2   103   102   100K
EREF   100 0   103 0 1
R100   100   0   1MEG
*
.model NPN  NPN(BF=50000)
*
.ENDS


Ed i risultati sono questi:

Amplificatore + filtro ellittico CC 04 08 31 1

analysis_f.png (7.42 KiB) Osservato 3470 volte

Attorno alla banda passante:

Zoom attorno alla banda passante

analysis_f_zoom.png (5.32 KiB) Osservato 3456 volte

Si nota una buona selettività del filtro, ma il comportamento della fase è più tormentato nelle vicinanze della frequenza di taglio.
Lascio a voi vedere come si comporta il filtro utilizzando componenti standard all'1% e verificare che non sia troppo sensibile alle tolleranze.
Volendo, si potrebbe fare a meno del filtro notch, mettendo una coppia di zeri a 50Hz in una seconda cellula di Friend, ma in versione notch/passa alto invece che la Sallen/Key. Ho paura però che il circuito inzi a diventare un po' critico...

Mi dite cosa ne pensate?

[belva87]

Direi che è tutto molto interessante, però ormai è difficile continuare se la nostra amica non ci comunica che intenzioni ha riguardo il campionamento, perché credo che con il mio e il tuo filtro, ormai siamo arrivati a buon punto, però la soluzione migliore è sempre quella che scaturisce da una conoscenza totale del problema, e dopo aver posto tutti i parametri a tavolino... tipo, per l'alias... la frequenza di campionamento è un po' come l'asse di briscola
Per il modello e le simulaizioni invece sto notando che esiste diversa roba in rete, però non riesco a caricarlo nel mio LTSpice in particolare ho sotto mano il TL072, che è lownoise, ufficiale della ST che di seguito riporto:

Codice: Seleziona tutto

* TL072 OPERATIONAL AMPLIFIER "MACROMODEL" SUBCIRCUIT
* CREATED USING PARTS RELEASE 4.01 ON 06/16/89 AT 13:08
* (REV N/A)      SUPPLY VOLTAGE: +/-15V
* CONNECTIONS:   NON-INVERTING INPUT
*                | INVERTING INPUT
*                | | POSITIVE POWER SUPPLY
*                | | | NEGATIVE POWER SUPPLY
*                | | | | OUTPUT
*                | | | | |
.SUBCKT TL072    1 2 3 4 5
*
  C1   11 12 3.498E-12
  C2    6  7 15.00E-12
  DC    5 53 DX
  DE   54  5 DX
  DLP  90 91 DX
  DLN  92 90 DX
  DP    4  3 DX
  EGND 99  0 POLY(2) (3,0) (4,0) 0 .5 .5
  FB    7 99 POLY(5) VB VC VE VLP VLN 0 4.715E6 -5E6 5E6 5E6 -5E6
  GA    6  0 11 12 282.8E-6
  GCM   0  6 10 99 8.942E-9
  ISS   3 10 DC 195.0E-6
  HLIM 90  0 VLIM 1K
  J1   11  2 10 JX
  J2   12  1 10 JX
  R2    6  9 100.0E3
  RD1   4 11 3.536E3
  RD2   4 12 3.536E3
  RO1   8  5 150
  RO2   7 99 150
  RP    3  4 2.143E3
  RSS  10 99 1.026E6
  VB    9  0 DC 0
  VC    3 53 DC 2.200
  VE   54  4 DC 2.200
  VLIM  7  8 DC 0
  VLP  91  0 DC 25
  VLN   0 92 DC 25
.MODEL DX D(IS=800.0E-18)
.MODEL JX PJF(IS=15.00E-12 BETA=270.1E-6 VTO=-1)
.ENDS

Tu Darwin sai come aiutarmi a farlo digerire al software di simulazione?
Poi un'altra cosa, la paura per la 50Hz è chiara ma, perché arrabattarsi tanto? è molto sotto i 300Hz e senza il notch si ha già una attenuazione notevole.. sbaglio? poi si spera che questi neuroni non siano appoggiati sopra un trasformatore da rete
Ora come ora comunque, a parte le nostre smanie di simulazione (valide direi...) è ora, come già detto in passato da entrambi, di fare un nuovo progetto solo se si hanno dati in più, altrimenti... costruire

[DirtyDeeds]

Per il modello e le simulaizioni invece sto notando che esiste diversa roba in rete, però non riesco a caricarlo nel mio LTSpice

Che errore ti dà, esattamente?

[IsidoroKZ]

Continuo ad avere un dubbio sulla impedenza di ingresso di tutti quei circuiti, in particolare per quanto riguarda la componente capacitiva.

Ricordo che per il front end si facevano circuiti a retroazione positiva per compensare l'impedenza di ingresso dell'amplificatore, altrimenti il neurone non ce la fa a pilotare il carico.

Non ricordo se te l'ho gia` chiesto, giulia87 dove e che cosa studi?

[belva87]

Difatti, lo abbiamo detto più volte il discorso dell'impedenza di ingresso..però boh, Giulia è scomparsa...
L'errore è semplice, mi dice che non esiste un subcircuit chiamato: " ( ... ) tl072 opamps " dove dentro le parentesi ci sono tutti i nodi del circuito dove insiste l'operazionale...
Io ho impiegato il simbolo già esistente sotto la categoria opamps, scorrendo il menù fino alla fine... e nella dicitura dice: " Basic operational amplifier for use with subcircuits in the file ./lib/sub/LTC.lib you must give the value a name and include this file."
Che con il mio umile inglese dovrebbe voler dire, che quel simbolo è di base e che è utilizzabile attraverso un subcircuit che deve stare nel file "percorso" e che si deve definire i valori e il nome includendo il tutto nel file...
Ora io ho preso il mio bel file TXT e l'ho rinominato LIB e l'ho messo nella directory specificata... e l'errore è quello descritto sopra... ho forse sbagliato a non includerlo? credo di si... ma non so come fare da direttiva... oppure sbaglio proprio metodo? se sapete aiutarmi vi ringrazio molto perché lo Spice della Cadence che avevo, la versione student, sul 7 ogni volta che finisce una simulazione si impianta... e poi è limitato in componentistica e non trovo la crack funzionante...

[DarwinNE]

Continuo ad avere un dubbio sulla impedenza di ingresso di tutti quei circuiti, in particolare per quanto riguarda la componente capacitiva.

Sono d'accordo. Avevamo discusso dell'impedenza del neurone e giulia87 aveva anche citato un circuito equivalente piuttosto articolato (messaggi [15], [16] e [17]), ma senza fornire nessun valore dei parametri equivalenti. Poi per divertirci abbiamo fatto di tutto e di più con filtrini e abbiamo piacevolmente discusso di simulazione, ma senza avere i dati che ci servono è stato praticamente tempo perso per il problema iniziale.
Sarebbe anche utile sapere di più su tutto il sistema. Per esempio, se le uscite di ogni via vanno alle schede di acquisizione con un cavo coassiale non cortissimo, potrebbe darsi che gli operazionali si mettano ad autooscillare per via del carico capacitivo che esso rappresenta...

Io ho impiegato il simbolo già esistente sotto la categoria opamps, scorrendo il menù fino alla fine... e nella dicitura dice: " Basic operational amplifier for use with subcircuits in the file ./lib/sub/LTC.lib you must give the value a name and include this file."

Boh? Io LTspice l'ho usato pochino perché ho Altium al lavoro e per via del problema con Windows di cui parlavo sopra. Come hai visto, io tendo a preferire lo SPICE di base, anche se mi hanno parlato molto bene di Ngspice (che però non ho ancora mai provato).
Io fossi in te, cercherei un esempio nei manuali di LTspice e partireri da lì per capire come inserire un nuovo modello di simulazione.